MAX7219 Display Driver - Controlando um Display de 7 Segmentos com o Arduino

Como primeiro exercício prático com o MAX7219, vou ligá-lo a um display de 7 segmentos com quatro dígitos e a um Arduino.

Hardware

O display de quatro dígitos simplifica as ligações entre os módulos, já que os segmentos estão interligados internamente. O Arduino utilizado é um Nano, que pode ser colocado diretamente na protoboard. Embora seja possível (e até preferível do ponto de vista de desempenho) usar a interface SPI do ATmega, nesta montagem liguei o MAX7219 a três saídas digitais quaisquer e gerei "na mão" os sinais de comunicação (com uma pequena ajuda da biblioteca do Arduino).

O circuito possui somente três componentes discretos: o resistor que define a corrente nos segmentos e dois capacitores. A finalidade destes capacitores é filtrar as interferências geradas na alimentação pelo liga/desliga dos LEDs.

Software

O software é bastante simples mas ilustra o básico do uso do MAX7219 no comando de displays de 7 segmentos.

// Conecões ao MAX7219
#define PIN_LOAD 6
#define PIN_DIN  5
#define PIN_CLK  4

#define LED      13

// Registradores do MAX7219
#define MAX7219_NOP   0x00
#define MAX7219_DIG0  0x01
#define MAX7219_DIG1  0x02
#define MAX7219_DIG2  0x03
#define MAX7219_DIG3  0x04
#define MAX7219_DIG4  0x05
#define MAX7219_DIG5  0x06
#define MAX7219_DIG6  0x07
#define MAX7219_DIG7  0x08
#define MAX7219_MODE  0x09
#define MAX7219_INT   0x0A
#define MAX7219_LIM   0x0B
#define MAX7219_SHUT  0x0C
#define MAX7219_TEST  0x0F

// CONEXOES DOS LEDS
#define DIG1   MAX7219_DIG0
#define DIG2   MAX7219_DIG1
#define DIG3   MAX7219_DIG2
#define DIG4   MAX7219_DIG3

uint8_t cont [4];

// Iniciação
void setup ()
{
  pinMode (LED, OUTPUT);
  pinMode (PIN_LOAD, OUTPUT);
  pinMode (PIN_DIN, OUTPUT);
  pinMode (PIN_CLK, OUTPUT);
  digitalWrite (PIN_LOAD, HIGH);
  digitalWrite (PIN_CLK, LOW);
  digitalWrite (PIN_DIN, LOW);
  
  write7219 (MAX7219_SHUT, 0x00);
  write7219 (MAX7219_TEST, 0x00);
  write7219 (MAX7219_MODE, 0x0F);
  write7219 (MAX7219_INT, 0x0F);
  write7219 (MAX7219_LIM, 0x03);
  write7219 (DIG1, 12);  // H
  write7219 (DIG2, 11);  // E
  write7219 (DIG3, 13);  // L
  write7219 (DIG4, 14);  // P
  write7219 (MAX7219_SHUT, 0x01);
  delay (2000);
  for (int i = 0; i < 4; i++)
    cont[i] = 0;
}

// Loop Principal
void loop ()
{
  // Mostra o contador atual
  write7219 (DIG1, cont[0]);
  write7219 (DIG2, cont[1]);
  write7219 (DIG3, cont[2]);
  write7219 (DIG4, cont[3]);

  // Soma 1 no contador
  for (int i = 3; i >= 0; i--)
  {
    if (cont[i] < 9)
    {
      cont[i]++;
      break;
    }
    cont[i] = 0;
  }
  delay (100);
}

// Escreve um dado no registrador addr do MAX7219
void write7219 (uint8_t addr, uint8_t data)
{
  digitalWrite (PIN_LOAD, LOW);
  shiftOut (PIN_DIN, PIN_CLK, MSBFIRST, addr);
  shiftOut (PIN_DIN, PIN_CLK, MSBFIRST, data);
  digitalWrite (PIN_LOAD, HIGH);
}

Resultado

O vídeo abaixo mostra a montagem funcionando.